'********************************************************************

'*

'* Function CSVJoin

'*

'*   Author: NetworkAdminKB.com

'*  Created: 2008-05-24

'* Modified: 2008-05-24

'*

'* Purpose: Returns an comma delimited string from an array with the

'*             individual values in quotes (or another qualifier).

'*             This is similar to the VBScript Join function.  However,

'*             this function qualifies the individual values as well.

'*

'* Input:  aryAny        Any Array of values.

'*         strDelimiter  The delimiter for the values in the array.

'*                         Default = ","

'*         strQualifier  The qualifier for the values.

'*                         Default is none (Empty)

'*

'* Output:  Returns an comma delimited string from an array with the

'*             individual values in quotes (or another qualifier).

'*          Returns Empty if aryAny is not an Array

'*

'* Changes:

'********************************************************************

Function CSVJoin(ByRef aryAny, ByVal strDelimiter, ByVal strQualifier)

  'Version 1.0 2008-05-24

  Dim x, strNew

 

  'Set default if not specified

  If Len(strDelimiter) = 0 Then strDelimiter = ","

 

  If IsArray(aryAny) Then

    strNew = strQualifier & Join(aryAny, strQualifier & strDelimiter & _

               strQualifier) & strQualifier

  Else

    strNew = Empty

  End If 'IsArray(aryAny)

  CSVJoin = strNew

End Function 'CSVJoin

'********************************************************************

'*

'* Function RPadString

'*

'*   Author: NetworkdAdminKB.com

'*  Created: 2007-01-07

'* Modified: 2007-01-07

'*

'* Purpose: On the right side Pad a string with the specified character

'*            until it is the specified length.

'*

'* Input:   strAny = The string to pad

'*          intLen = The total string length after padding

'*          strPad = The character string to suffix strAny with.

'*

'* Output:  Returns the string suffixed with the specified character

'*            to the specified length.

'*          Returns the existing string if Length(strAny) >= intLen

'*          Returns Empty if an error occurs

'*

'********************************************************************

Function RPadString(ByVal strAny, ByVal intLen, ByVal strPad)

  'Version: 1.0 2007-01-07

  Dim strTemp, x

 

  If Len(strPad) <> 1 Then

    Wscript.Echo "RPadString: strPad must be one character in length."

    RPadString = Empty

    Exit Function

  End If 'Len(strPad) <> 1

 

  If Len(strAny) < intLen Then

    For x = 1 to (intLen - Len(strAny))

      strTemp = strTemp & strPad

    Next 'x

    RPadString = strAny & strTemp

  Else

    RPadString = strAny

  End If 'Len(strAny) < intLen

 

End Function 'RPadString